***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan. 15, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4526P-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.356
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=234.2  VTO=2.221  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=6.0964e11  gamma=0.72)
Rd     d1    d2    3.182e-3    TC=3.11e-3,9.29e-6
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=33  TBV1=3.871e-4 TBV2=-1.57e-7  CJO=1.24e-9  M=0.8682  VJ=8.702)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=8.116e-11  N=1.173  RS=4e-8  EG=1.14  TT=20n IKF=53.471 tikf=9.5e-3)
Rdiode  d1  21    2.344e-3 TC=5.1e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   2.228e-10
.MODEL     DGD    D(cjo=2.095e-10   M=1.507   VJ=6.539)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    7.38e-10
.ENDS PJQ4526P-AU
*$
